Public Function Str_TrimR(ByVal MyString As String, ByVal Char As String) As String
'Purpose
'   Used to remove all instances of a specified trailing character from a string.
'Parameters
'   MyString (String) = The string we're working with.
'   Char (String) = The character we want to remove from the end of the specified string.
'       If this contains more than one character, only the first character is used.
'Return (String)
'   Returns the specified string (MyString) with all instances of the specified trailing
'       character (Char) removed.
'   Returns the specified string (MyString) if:
'       - The specified string (MyString) has no trailing instances of the specified character (Char).
'       - The specified character (Char) is zero-length.
'   Returns a zero-length string if:
'       - The specified string (MyString) contains only the specified character (Char).
'       - The specified string (MyString) is zero-length.
'Version History
'   1.0 6/15/06 11:52pm Tested by Russ Tanner on VB6 Win2000
'---

'Trap: The specified character is zero-length, return MyString and return now
If Char = "" Then
    Str_TrimR = MyString
    Exit Function
End If

'We only want to use the first character of the specified Char
Char = Left(Char, 1)

'Trim all trailing slashes
Do While Right(MyString, 1) = Char
    MyString = Left(MyString, Len(MyString) - 1)
Loop

'Return the result
Str_TrimR = MyString

End Function